Image:Truncated octahedra.jpg
From Wikipedia, the free encyclopedia
No higher resolution available.
Truncated_octahedra.jpg (256 × 256 pixels, file size: 12 KB, MIME type: image/jpeg)
| This is a file from the Wikimedia Commons. The description on its description page there is shown below.
|
La bildo estas kopiita de wikipedia:en. La originala priskribo estas:
Tesselation of space using truncated octahedra. See truncated octahedron.
Created by Andrew Kepert using povray in May 2004. All rights reversed. It is a modification of the povray code I used for the similar image on rhombic dodecahedron.
[edit] Povray code
[edit] File "truncated_octahedra.pov"
#include "colors.inc"
#include "math.inc"
#include "rand.inc"
//#include "truncated_octahedron.povi"
#declare A=sqrt(3);
#declare truncoct =
intersection {
box { < -2,-2,-2>, <2,2,2> }
plane { < 1, 1, 1>, A }
plane { < 1, 1,-1>, A }
plane { < 1,-1, 1>, A }
plane { < 1,-1,-1>, A }
plane { <-1, 1, 1>, A }
plane { <-1, 1,-1>, A }
plane { <-1,-1, 1>, A }
plane { <-1,-1,-1>, A }
}
//end of inclusion "truncated_octahedron.povi"
global_settings{ ambient_light White }
background { color White }
#declare LX = 60;
#declare LZ = 100;
light_source { <LX,-LX,LZ> color White}
light_source { <-LX,LX,LZ> color White}
light_source { <LX,LX,LZ> color White}
light_source { <-LX,-LX,LZ> color White}
#declare extent = 3 ;
#declare i = -extent;
#while ( i <= extent )
#declare j = -extent;
#while ( j <= extent )
#declare k = -extent;
#while ( k <= extent )
#if ( even(i+j) & even(i+k) & ( i+j+2*k<3*extent ) & Prob(0.95, RdmD))
#declare RCOLOUR = rgb < Rand_Normal( 0.6, 0.2, RdmA ) ,
Rand_Normal( 0.4, 0.2, RdmB ) ,
Rand_Normal( 0.6, 0.2, RdmC ) > ;
#declare COLANG = rand(RdmA)*2*3.14159;
object { truncoct
scale 0.48
translate < i, j, k >
texture {
pigment { color RCOLOUR }
finish { ambient 0.3 diffuse 0.3 phong Rand_Normal( 0.5, 0.2, RdmC ) }
}
}
#end // if
#declare k = k+1;
#end // while k
#declare j = j+1;
#end // while j
#declare i = i+1;
#end // while i
camera {
location 28*y
direction -y
right 0.4*x
up 0.4*z
rotate 20*x
rotate -30*z
translate -0.5*z
}
| date/time | username | edit summary |
|---|---|---|
| 01:51, 10 March 2006 | en:User:Tomruen | (<a href="/wiki/Category:Honeycomb_image" title="Category:Honeycomb image">Category:Honeycomb image</a>) |
| 07:09, 8 September 2004 | en:User:Chmod007 | (GFDL) |
| 00:35, 24 May 2004 | en:User:AndrewKepert | (upload log, povray code) |
| 00:28, 24 May 2004 | en:User:AndrewKepert | (Tesselation of space using truncated octahedra) |
[edit] Historio de la dosiero
Legend: (cur) = this is the current file, (del) = delete this old version, (rev) = revert to this old version.
Click on date to download the file or see the image uploaded on that date.
- (del) (cur) 00:28, 24 May 2004 . . en:User:AndrewKepert AndrewKepert ( en:User_talk:AndrewKepert Talk) . . 256x256 (12080 bytes) (Tesselation of space using truncated octahedra)
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Dimensions | User | Comment | |
|---|---|---|---|---|
| current | 16:48, 18 March 2006 | 256×256 (12 KB) | Maksim | (La bildo estas kopiita de wikipedia:en. La originala priskribo estas: Tesselation of space using truncated octahedra. See truncated octahedron. Category:Honeycomb image Created by Andrew Kepert using povray in May 2004) |
File links
The following pages on the English Wikipedia link to this file (pages on other projects are not listed):
