Image:Three types.png

[edit] Summary

The gnuplot sourcecode used is as follow:

# This file is used to generate a plot that explains the 
# three PWM: centered, tail edge modulated and lead edge modulated

# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24 color solid
set encoding iso_8859_15
unset title
set line style 1 lt 3 lw 3 pt 0 ps 0
set line style 2 lt 2 lw 1 pt 0 ps 0
set border 15 lt 7 lw 4

set grid xtics ytics mxtics
set xlabel ""
set samples 10000
set format x ""
set bmargin 0
set tmargin 0

# equation of the trail modulation saw signal
trailsignal(x) = x-floor(x)
# equation of the lead modulation saw signal
leadsignal(x) = ceil(x)-x
#equation of the centered triangular signal
centersignal(x)=abs(x-1-floor(x-0.5))*2
#equation of the sine signal
freq=0.05
sinesignal(x) = 0.5+0.49*sin(freq*x*(2*pi))

#equation of the resulting pwm lead signal
pwmleadsignal(x)=leadsignal(x)>=sinesignal(x)?0:1
#equation of the resulting pwm trail signal
pwmtrailsignal(x)=trailsignal(x)>=sinesignal(x)?0:1
#equation of the resulting pwm center signal
pwmcentersignal(x)=centersignal(x)>=sinesignal(x)?0:1

set ytics ("0" 0, "1" 1)
set mxtics 2
set output "three_types.eps"
set multiplot
        set ylabel "lead"
        set origin 0,0.67
        set size 1,0.3
        plot [0:19][-0.25:1.25] leadsignal(x) ls 2 title '',\
        pwmleadsignal(x) ls 1 title ''

        set ylabel "trail"
        set origin 0,0.37
        plot [0:19][-0.25:1.25] trailsignal(x) ls 2 title '',\
        pwmtrailsignal(x) ls 1 title ''

        set ylabel "center"
        set origin 0,0.07
        set xlabel
        set format x "%1.0f T"
        plot [0:19][-0.25:1.25] centersignal(x) ls 2 title '',\
        pwmcentersignal(x) ls 1 title ''
unset multiplot

the eps file generated is converted in png by the following command (linux)

convert -density 300 three_types.eps three_types.png 

[edit] Licensing

I, the copyright holder of this work, hereby publish it under the following licenses: Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation license, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation license". Aragonés | العربية | Asturianu | Български | বাংলা | ইমার ঠার/বিষ্ণুপ্রিয়া মণিপুরী | Brezhoneg | Bosanski | Català | Cebuano | Česky | Dansk | Deutsch | Ελληνικά | English | Esperanto | Español | Eesti | Euskara | فارسی | Suomi | Français | Gaeilge | Galego | עברית | Hrvatski | Magyar | Bahasa Indonesia | Ido | Íslenska | Italiano | 日本語 | ქართული | ភាសាខ្មែរ | 한국어 | Kurdî / كوردی | Latina | Lëtzebuergesch | Lietuvių | Bahasa Melayu | Nnapulitano | Nederlands | ‪Norsk (nynorsk)‬ | ‪Norsk (bokmål)‬ | Occitan | Polski | Português | Română | Русский | Slovenčina | Slovenščina | Shqip | Српски / Srpski | Svenska | తెలుగు | ไทย | Türkçe | Українська | اردو | Tiếng Việt | Volapük | Yorùbá | ‪中文(中国大陆)‬ | ‪中文(台灣)‬ | +/- This file is licensed under the Creative Commons Attribution ShareAlike license versions 2.5, 2.0, and 1.0 العربية | Български | Català | Česky | Dansk | Deutsch | English | Español | Euskara | فارسی | Français | עברית | Italiano | 日本語 | 한국어 | Lietuvių | Nederlands | Polski | Português | Русский | Svenska | தமிழ் | Türkçe | 中文 | 中文 | +/- You may select the license of your choice.

• Pulse-width modulation