STO-nG basis sets

From Wikipedia, the free encyclopedia

1 STO-nG basis sets

[edit] STO-nG basis sets

STO-nG basis sets are the minimal basis sets, where 'n' represents the number of primitive Gaussian functions comprising a single basis set. For minimal basis sets, the core and valence orbitals are represented by same number primitive Gaussian functions $\mathbf \phi_i$ . For example, an STO-3G basis set for the 1s orbital of H atom is a linear combination of 3 primitive Gaussian functions. It is easy to calculate the energy of an electron in the 1s orbital of H atom represented by STO-nG basis sets. In the following sections, the structure of the STO-nG minimal basis sets are explained with H atom as an example.

[edit] STO-1G basis set

$\mathbf \psi(1s_H)= \psi_{STO-1G}=c_1\phi_1$ , where $\mathbf c_1 = 1$ and $\mathbf \phi_1 = \left (\frac{2\alpha_1}{\pi} \right ) ^{0.75}e^{-\alpha_1 r^2}$ . The optimum value of $\mathbf \alpha_1$ is the one which gives the minimum value for the Energy of the 1s electron of H atom. The exponent $\mathbf \alpha_1$ for the STO-1G basis set can be manually derived by equating the derivative of the energy with respect to the exponent to zero.
Thus $\mathbf \alpha_1 = \frac{8 Z^2}{9 \pi} = 0.28294212$ and for the value $\mathbf \alpha_1 = 0.28294212$ , the energy of the 1s electron of H atom can be calculated as $\mathbf -0.42441318$ hartree. The expression for the energy of the 1s electron of H atom is a function only of $\mathbf c_1$ , $\mathbf \alpha_1$ and other fundamental constants such as $\mathbf \pi$ . For convenience, the basis set details can be represented as follows

STO-1G	$\mathbf \alpha$	$\mathbf c$
	0.2829421200D+00	1.0000000000D+00

[edit] STO-2G basis set

In general an STO-nG basis set is a linear combination of n primitive Gaussian functions. The STO-nG basis sets are usually represented by the exponents and the corresponding coefficients. Thus an STO-2G [Ref. 1] basis set which is a linear combination of 2 primitive Gaussian functions can be represented as follows.

STO-2G	$\mathbf \alpha$	$\mathbf c$
	0.1309756377D+01	0.4301284983D+00
	0.2331359749D+00	0.6789135305D+00

[edit] Accuracy

The exact energy of the 1s electron of H atom is -0.5 hartree. Following table illustrates the increase in accuracy as the number of primitive Gaussian functions increases in the basis set.

Basis set	Energy [hartree]
STO-1G	-0.424413182
STO-2G [Ref. 1]	-0.454397402
STO-3G [Ref. 1]	-0.466581850
STO-4G	-0.469806464
STO-5G	-0.470742918
STO-6G [Ref. 1]	-0.471039054

[edit] Calculation of electronic energy using STO-nG basis sets (For ex. H atom)

The electronic energy of a molecular system is calculated as the expectation value of the molecular electronic Hamiltonian :

$\mathbf E_{elec} = \frac{<\psi_{STO-nG}|\mathbf \hat{H}_e|\psi_{STO-nG}>}{<\psi_{STO-nG}|\psi_{STO-nG}>}$ ,

where $\mathbf \hat{H}_e$ is the electronic hamiltonian of the molecule. The expectation values can be analytically solved only for a two body system such as a Hydrogen atom. The electronic Hamiltonian for H-atom is given by $\mathbf \hat{H}_e = -\frac{\nabla^2}{2}-\frac{Z}{r}$ .
The exact integrals for the kinetic energy, potential energy expectation values and overlap integrals can be obtained as follows

$\mathbf E_{elec} = \frac{<\psi_{STO-nG}|-\frac{\nabla^2}{2}-\frac{Z}{r}|\psi_{STO-nG}>}{<\psi_{STO-nG}|\psi_{STO-nG}>}$ ,

$\mathbf E_{elec} = \frac{<\sum_{i=1}^n c_i \phi_i|-\frac{\nabla^2}{2}|\sum_{j=1}^n c_j \phi_j> + <\sum_{i=1}^n c_i \phi_i|-\frac{Z}{r}|\sum_{j=1}^n c_j \phi_j>}{<\sum_{i=1}^n c_i \phi_i|\sum_{j=1}^n c_j \phi_j>}$ ,

$\mathbf E_{elec} = \frac{<\sum_{i=1}^n c_i \phi_i|T|\sum_{j=1}^n c_j \phi_j> + <\sum_{i=1}^n c_i \phi_i|V|\sum_{j=1}^n c_j \phi_j>}{<\sum_{i=1}^n c_i \phi_i|\sum_{j=1}^n c_j \phi_j>}$ .

Now the total energy expectation value can be divided into 3 parts, the kinetic energy expectation value, the potential energy expectation value and the overlap integrals.

$\mathbf E_{elec} = \frac{<T>+<V>}{S}$ where,

$\mathbf <T> = \frac {6\sqrt{2}\sum_{i=1}^n \sum_{j=1}^n c_i c_j (\alpha_i\alpha_j)^{7/4}}{(\alpha_i+\alpha_j)^{5/2}}$ ,

$\mathbf <V> = \frac {-4\sqrt{2}Z \sum_{i=1}^n \sum_{j=1}^n c_i c_j (\alpha_i\alpha_j)^{3/4}}{\sqrt{\pi}(\alpha_i+\alpha_j)}$ ,

$\mathbf S = \frac {2\sqrt{2} \sum_{i=1}^n \sum_{j=1}^n c_i c_j (\alpha_i\alpha_j)^{3/4}}{(\alpha_i+\alpha_j)^{3/2}}$ .

Thus when an STO-nG basis set with n Gaussian promitives is used, there are $n 2$ kinetic energy integrals, $n 2$ potential energy integrals and $n 2$ overlap integrals. Thus with $n$ primitive GTFs in the basis set, we need $3 n 2$ integrals.

[edit] Appendix

The basis sets STO-nG [n=2,3&6] can be referred from the online basis set exchange [Ref. 1] and the energy of the 1s electron of H atom can easily be calculated by hand or by using a small program. Following is a Fortran77 program where the energy expression is explicitly stated and by giving the basis set as the input, the energy value is obtained as output.

     !----------------------------------------------------------------
     ! PROGRAM sto_ng CALCULATES THE ENERGY OF 1s ELECTRON OF "H" ATOM
     ! OR OTHER HYDROGENIC ATOMIC SYSTEMS WITH MINIMAL BASIS SETS. THE
     ! PROGRAM CAN BE EASILY EXTENDED FOR LARGER BASIS SETS. 
     !----------------------------------------------------------------
     PROGRAM sto_ng
     IMPLICIT NONE
     !----------------------------------------------------------------
     ! i AND j : DUMMY INDICES
     !       n : NUMBER OF PRIMITIVE GTOs
     !       Z : ATOMIC NUMBER
     !----------------------------------------------------------------
     INTEGER i, j, n, Z
     !----------------------------------------------------------------
     !  V(i,j) : i,j TH ELEMENT OF THE POTENTIAL ENERGY MATRIX
     !  T(i,j) : i,j TH ELEMENT OF THE KINETIC ENERGY MATRIX
     !  S(i,j) : i,j TH ELEMENT OF THE OVERLAP INTEGRAL MATRIX
     !      VI : TOTAL SUM OF ALL POTENTIAL ENERGY INTEGRALS
     !      TI : TOTAL SUM OF ALL KINETIC ENERGY INTEGRALS
     !      SI : TOTAL SUM ALL OF OVERLAP INTEGRALS
     !    c(i) : i TH COEFFICIENT
     !alpha(i) : i TH EXPONENT
     !----------------------------------------------------------------
     DOUBLE PRECISION V(100,100), T(100,100), S(100,100)
     DOUBLE PRECISION alpha(100), c(100), VI, TI, SI, PI
     PI=3.1415926535898D0
     OPEN(UNIT=1, FILE="input.txt")
     OPEN(UNIT=2, FILE="output.txt")
     READ(1,*)Z,n
     DO i=1,n
        READ(1,*)alpha(i),c(i)
     ENDDO
    !----------------------------------------------------------------
    ! CALCULATION OF OVERLAP INTEGRALS AND THEIR SUMMATION
    !----------------------------------------------------------------
     DO i=1,n
        DO j=1,n
          S(i,j)=c(i)*c(j)*2.0D0*SQRT(2.0D0)*(alpha(i)*alpha(j))**0.75D
    &0/(alpha(i)+alpha(j))**(1.5D0)
        ENDDO
     ENDDO
     SI=0.0D0
     DO i=1,n
        DO j=1,n
           SI=SI+S(i,j)
       ENDDO
     ENDDO
    !----------------------------------------------------------------
    ! CALCULATION OF KINETIC ENERGY INTEGRALS AND THEIR SUMMATION
    !----------------------------------------------------------------
     DO i=1,n
        DO j=1,n
        T(i,j)=c(i)*c(j)*6.0D0*SQRT(2.0D0)*(alpha(i)*alpha(j))**1.75D0/
    &(alpha(i)+alpha(j))**(2.5D0)
       ENDDO
     ENDDO
     TI=0.0D0
     DO i=1,n
        DO j=1,n
           TI=TI+T(i,j)
       ENDDO
     ENDDO
    !----------------------------------------------------------------
    ! CALCULATION OF POTENTIAL ENERGY INTEGRALS AND THEIR SUMMATION
    !----------------------------------------------------------------
     DO i=1,n
        DO j=1,n
          V(i,j)=-c(i)*c(j)*4.0D0*SQRT(2.0D0)*Z*(alpha(i)*alpha(j))**0.
    &75D0/(SQRT(PI)*(alpha(i)+alpha(j)))
        ENDDO
     ENDDO
     VI=0.0D0
     DO i=1,n
        DO j=1,n
           VI=VI+V(i,j)
       ENDDO
     ENDDO
     WRITE(2,*)"\n\nBasis set :\n"
     WRITE(2,002)"ALPHA(i)","C(i)"
     DO i=1,n
        WRITE(2,003)alpha(i),c(i)
     ENDDO
     WRITE(2,001)"\n\nK.E. integral is    :", TI," hartree"
     WRITE(2,001)"\nP.E. integral is    :", VI," hartree"
     WRITE(2,001)"\nOverlap Integral is :", SI," hartree"
     WRITE(2,001)"\nEnergy of H atom is :", (VI+TI)/SI," hartree/partic
    &le"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*27.211397D0/SI," e.V
    &./particle"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*627.509D0/SI," kcal/
    &mol"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*2625.51D0/SI," kJ/mo
    &l"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*219475D0/SI," cm-1"
 001 FORMAT(A,D20.10,A)
 002 FORMAT(8X,A,19X,A)
 003 FORMAT(D20.10,6X,D20.10)
 004 FORMAT(D20.10)
     CLOSE(1)
     CLOSE(2)
     STOP
     END

     INPUT FILE DETAILS
     FILE : input.txt
      1                                       ! ATOMIC NUMBER
      2                                       ! NO. OF PRIMITIVE GTOs
      0.1309756377D+01  0.4301284983D+00      ! BASIS SET  alpha c
      0.2331359749D+00  0.6789135305D+00

     OUTPUT FILE DETAILS
     FILE : output.txt
     Basis set :
         ALPHA(i)                   C(i)
     0.1309756377E+01          0.4301284983E+00
     0.2331359749E+00          0.6789135305E+00
     K.E. integral is    :    0.7348827001E+00 hartree
     P.E. integral is    :   -0.1189280102E+01 hartree
     Overlap Integral is :    0.1000000000E+01 hartree
     Energy of H atom is :   -0.4543974016E+00 hartree/particle
     ENERGY of H atom is :   -0.1236478809E+02 e.V./particle
     ENERGY of H atom is :   -0.2851384591E+03 kcal/mol
     ENERGY of H atom is :   -0.1193024922E+04 kJ/mol
     ENERGY of H atom is :   -0.9972886973E+05 cm-1