Image:Standard symmetric pdfs.png

[edit] Image summary

Plot of several symmetric unimodal probability densities with unit variance

From highest to lowest peak:

• red, kurtosis 3, Laplace (D)ouble exponential distribution
• orange, kurtosis 2, hyperbolic (S)ecant distribution
• green, kurtosis 1.2, (L)ogistic distribution
• black, kurtosis 0, (N)ormal distribution
• cyan, kurtosis −0.593762…, raised (C)osine distribution
• blue, kurtosis −1, (W)igner semicircle distribution
• magenta, kurtosis −1.2, (U)niform distribution

I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide. In case this is not legally possible: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law. Afrikaans | Alemannisch | Aragonés | العربية | Asturianu | Български | Català | Česky | Cymraeg | Dansk | Deutsch | Eʋegbe | Ελληνικά | English | Español | Esperanto | Euskara | Estremeñu | فارسی | Français | Galego | 한국어 | हिन्दी | Hrvatski | Ido | Bahasa Indonesia | Íslenska | Italiano | עברית | Kurdî / كوردی | Latina | Lietuvių | Latviešu | Magyar | Македонски | Bahasa Melayu | Nederlands | ‪Norsk (bokmål)‬ | ‪Norsk (nynorsk)‬ | 日本語 | Polski | Português | Ripoarisch | Română | Русский | Shqip | Slovenčina | Slovenščina | Српски / Srpski | Svenska | ไทย | Tagalog | Türkçe | Українська | Tiếng Việt | Walon | ‪中文(简体)‬ | ‪中文(繁體)‬ | zh-yue-hant | +/-

	This graph image should be recreated using vector graphics as an SVG file. This has several advantages; see Commons:Media for cleanup for more information. If an SVG form of this image is already available, please upload it. After uploading an SVG, replace this template with template {{Vector version available|new image name.svg}} in this image.
العربية | Български | Català | Česky | Dansk | Deutsch | English | Esperanto | Español | Français | 한국어 | Italiano | Magyar | Lietuvių | Nederlands | 日本語 | Polski | Português | Română | Русский | Suomi | Svenska | Türkçe | Українська | Tiếng Việt | मराठी | ‪中文(繁體)‬ | ‪中文(简体)‬ | +/-

[edit] Gnuplot source

# Laplace double exponential distribution, kurtosis 3
laplace(x) = exp(-abs(x)*sqrt(2)) * sqrt(0.5)

# sech distribution, kurtosis 2
sech(x) = 2.0 / (exp(x) + exp(-x))
sech_pdf(x) = 0.5 * sech(0.5*pi*x)

# logistic distribution, kurtosis 1.2
slogist = sqrt(3) / pi
logist(x) = exp(-x/slogist) / slogist / (1 + exp(-x/slogist))**2

# normal distribution, kurtosis 0
n(x) = exp(-0.5*x*x) / sqrt(2*pi)

# raised cosine distribution, kurtosis -0.59376
scos = 1.0 / sqrt(1/3.0 - 2/pi**2)
cosine(x) = abs(x)>scos? 0 : (1+cos(x*pi/scos))*0.5/scos

# Wigner semicircle distribution, kurtosis -1
wigner(x) = abs(x)>2? 0 : sqrt(4-x*x)*0.5/pi

# uniform distribution, kurtosis -1.2
uniform(x) = abs(x)>sqrt(3)? 0 : 0.5/sqrt(3)


set samples 6001
set grid

set xrange [-5.4:5.4]
set xtics 1

set key 4, 0.77 Left enhanced

set terminal postscript enhanced color solid lw 1 "Courier" 14
set output "standard_symmetric_pdfs.ps"

plot \
     laplace(x)  lt 1 lw 2 title "D,  3", \
     sech_pdf(x) lt 8 lw 2 title "S,  2", \
     logist(x)   lt 2 lw 2 title "L,  1.2", \
     n(x)        lt 7 lw 2 title "N,  0", \
     cosine(x)   lt 5 lw 2 title "C, -0.59376", \
     wigner(x)   lt 3 lw 2 title "W, -1", \
     uniform(x)  lt 4 lw 2 title "U, -1.2"

set xrange [-10.4:10.4]

set logscale y
set yrange [1e-24:5]
set ytics 1e3

set key 7, 3e-19 Left enhanced

set terminal postscript enhanced color solid lw 1 "Courier" 14
set output "standard_symmetric_pdfs_logscale.ps"

replot

This work is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or any later version. This work is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See version 2 and version 3 of the GNU General Public License for more details. العربية | Català | Česky | Deutsch | Ελληνικά | English | Español | فارسی | Français | Italiano | 日本語 | Nederlands | Polski | Português | Русский | Slovenčina | Svenska | Türkçe | ‪中文(简体)‬ | ‪中文(繁體)‬ | +/-

[edit] See also

• Image:Standard symmetric pdfs logscale.png

• Kurtosis