User:Spl/Verilog
From Wikipedia, the free encyclopedia
Verilog is a hardware description language (HDL) used to model electronic systems. The language (sometimes called Verilog HDL) supports the design, testing, and implementation of analog, digital, and mixed-signal circuits at various levels of abstraction.
The designers of Verilog wanted a language with syntax similar to the C programming language so that it would be familiar to engineers and readily accepted. The language has a pre-processor like C, and the major control keywords such as "if", "while", etc are similar. The formating mechanism in the printing routines and language operators (and their precedence) are also similar.
The language differs in some fundamental ways. Verilog uses Begin/End instead of curly braces to define a block of code. The definition of constants in verilog require a bit width along with their base, consequently these differ. Verilog doesn't have structures, pointers, or recursive subroutines either. Finally, the concept of time so important to an HDL won't be found in C.
The language differs from a conventional programming language in that the execution of statements is not strictly linear. A Verilog design consists of a hierarchy of modules. Modules are defined with a set of input, output, and bidirectional ports. Internally, a module contains a list of wires and registers. Concurrent and sequential statements define the behaviour of the module by defining the relationships between the ports, wires, and registers. Sequential statements are placed inside a begin/end block and executed in sequential order within the block. But all concurrent statements and all begin/end blocks in the design are executed in parallel. A module can also contain one or more instances of another module to define sub-behavior.
A subset of statements in the language is synthesizable. If the modules in a design contain only synthesizable statements, software can be used to transform or synthesize the design into a netlist that describes the basic components and connections to be implemented in hardware. The netlist may then be transformed into, for example, a form describing the standard cells of an integrated circuit (e.g. an ASIC) or a bitstream for a programmable logic device (e.g. a FPGA).
Contents |
[edit] Features
[edit] Overview
[edit] Example
A simple example of two flip-flops follows:
module toplevel(clock,reset);
input clock;
input reset;
reg flop1;
reg flop2;
always @ (posedge reset or posedge clock)
if (reset)
begin
flop1 <= 0;
flop2 <= 1;
end
else
begin
flop1 <= flop2;
flop2 <= flop1;
end
endmodule
The "<=" operator in verilog is another aspect of its being a hardware description language as opposed to a normal procedural language. This is known as a "non-blocking" assignment. When the simulation runs, all of the signals assigned with a "<=" operator have their assignment scheduled to occur after all statements occurring during the same point in time have executed. After all the statements have been executed for one event, the scheduled assignments are performed. This makes it easier to code behaviours that happen simultaneously.
In the above example, flop1 is assigned flop2, and flop2 is assigned flop1. These statements are executed during the same time event. Since the assignments are coded with the "<=" non-blocking operator, the assignments are scheduled to occur at the end of the event. Until then, all reads to flop1 and flop2 will use the values they had at the beginning of the time event.
This means that the order of the assignments are irrelevant and will produce the same result. flop1 and flop2 will swap values every clock.
The other choice for assignment is an "=" operator and this is known as a blocking assignment. When the "=" operator is used, things occur in the sequence they occur much like a procedural language.
In the above example, if the statements had used the "=" blocking operator instead, then the order of the statements would affect the behaviour. If the same code were used but changed to "=" operators, the reset would set flop2 to a 1, and flop1 to a 0. A clock event would set flop1 to flop2 (a 1) and this assignment would happen immediately. The next statement would assign flop2 to flop1, which is now a 1. Rather than swap values every clock, flop1 and flop2 would both become 1 and remain that way.
An example counter circuit follows:
module Div20x (rst, clk, cet, cep, count,tc);
//TITLE 'Divide-by-20 Counter with enables'
//enable CEP is a clock enable only
//enable CET is a clock enable and enables the TC output
//a counter using the Verilog language
parameter size = 5;
parameter length = 20;
input rst; // These inputs/outputs represent connections to
input clk; // the module.
input cet;
input cep;
output [size-1:0] count;
output tc;
reg [size-1:0] count; // Signals assigned within an always (or initial) block
// must be of type reg
wire tc; // Other signals are of type wire
// The always statement below is a parallel execution statement that
// executes any time the signals rst or clk transition from low to high
always @ (posedge rst or posedge clk)
if (rst) // This simulates a reset of the counter
count <= 5'b0;
else
if (cet && cep) // This simulates the enables both being true
begin
if (count == length-1)
count <= 5'b0;
else
count <= count + 5'b1; // 5'b1 is 5 bits wide and
end // equal to the value 1.
// the value of tc is continuously assigned the value of the expression
assign tc = (cet && (count == length-1));
endmodule
Example:
...
reg a, b, c, d;
wire e;
...
always @(b or e)
begin
a = b & e;
b = a | b;
#5 c = b;
d = #6 c ^ e;
end
The always clause above illustrates the other type of method of use, i.e. the always clause executes any time any of the entities in the list change, i.e. the b or e change. When one of these changes, immediately a and b are assigned new values. After a delay of 5 time units, c is assigned the value of b and the value of c ^ e is tucked away in an invisible store. Then after 6 more time units, d is assigned the value that was tucked away.
Signals that are driven from within a process (an initial or always block) must be of type reg. Signals that are driven from outside a process must be of type wire. The keyword reg does not necessarily infer a hardware register.
[edit] Levels of abstraction
[edit] Similarity to C
[edit] Definition of Constants
The definition of constants in Verilog supports the addition of a width paramter. The basic syntax is:
<Width in bits>`<base><number>
Examples: 12'h123 - Hexidecimal 123 (using 12 bits) 20'd44 - Decimal 44 (using 20 bits - 0 extension is automatic) 4'b1010 - Binary 4 (using 4 bits) 6'o77 - Octal 77 (using 6 bits)
[edit] Synthesizeable constructs
As mentioned previously, there are several basic templates that can be used to represent hardware.
// Mux examples
// The first example uses continuous assignment
wire wire_out ;
assign wire_out = sel ? a : b;
// the second example uses a procedure to accomplish
// the same thing.
reg reg_out;
always @(a or b or sel)
reg_out = sel ? a: b;
// Finally - you can use if/else in a procedural structure.
reg if_out;
always @(a or b or sel)
if (sel)
if_out = a;
else
if_out = b;
The next interesting structure is a latch. A latch operates differently from a register. A latch will pass the input to the output when the gate signal is one state, while it was capture the input and store it at the transition of the gate signal. The output will remain stable while the input can transition when the gate signals the storage state.
// Latch example
reg latch_out;
always @(gate or din)
if(gate)
latch_out = din; // Pass through state
// Note that the else isn't required
// here. The variable will follow
// the value of din while the signal
// gate is high. when gate goes low,
// latch_out will remain constant.
The flip/flop is the next significant template. The basic D flop can be modeled as found below:
reg q; always @(posedge clk) q <= d;
The significant thing to notice in the D flop example is the first use of the non-blocking assignment. A basic rule of thumb is to use <= when there is a posedge or negedge statement within the always clause.
The next variant of the D flop is one with an asynchronous reset. There is a convention that the reset state will be the first if clause within the statement.
reg q;
always @(posedge clk or posedge reset)
if(reset == 1)
q <= 0;
else
q <= d;
The next variant is a flop including both an asynchronous reset and asynchronous set condition. Again the convention comes into play, i.e. the reset term is followed by the set term.
reg q;
always @(posedge clk or posedge reset or posedge set)
if(reset == 1)
q <= 0;
else
if(set == 1)
q <= 1;
else
q <= d;
The final basic variant of the flop is one that implements a flop with a mux feeding its input. The mux has a d input and feedback from the flop itself. This allows a gated load function.
// Basic structure with feedback path illustrated
always @(posedge clk)
if(gate)
q <= d;
else
q <= q;
// The more common structure ASSUMES the feedback is present
// This is a safe assumption since this is how the
// hardware compiler will interpret it. This structure
// looks much like a Latch. The differences are the
// <b>@(posedge clk)</b> and the non-blocking <b><=</b>
//
always @(posedge clk)
if(gate)
q <= din; // the mux is "implied"
Looking at the original counter example you can see a combination of the basic asynchronous reset flop and Gated input flop used. The register variable count is set to zero on the rising edge or rst. When rst is 0, the variable count will load new data when cet && cep is true.
[edit] System tasks
System tasks are available to handle simple I/O, and various design measurement functions. You'll note that all the system tasks start with a $. This section presents a short list of the most often used tasks. It is by no means a comprehensive list.
- $display - Print a line followed by an automatic newline.
- $write - Print a line without the newline.
- $readmemh - Read hex file content into a memory array.
- $readmemb - Read binary file content into a memory array.
- $monitor - Print out all the listed variables when any change value.
- $time - Value of current simulation time.
- $dumpfile - Declare the VCD ( Value Change Dump ) format output file name.
- $dumpvars - Turn on and dump the variables.
- $random - Return a random value.
[edit] Program Language Interface (PLI)
Program Language Interface provides a programmer with transferring control from Verilog to a program function written in C language as well as provides task function named tf_putlongp(), tf_getlongp which are used to write and read the argument of the current verilog task or function respectively.
This capability enables Verilog to cooperate with other programs written in C language such as test harness, Instruction Set Simulator of microcontroller, debugger, etc.
[edit] History
[edit] Beginning
Verilog was invented by Phil Moorby at Automated Integrated Design Systems (later renamed to Gateway Design Automation) in 1985 as a hardware modeling language. Gateway Design Automation was later purchased by Cadence Design Systems in 1990. Cadence now has full proprietary rights to Gateway's Verilog and the Verilog-XL simulator logic simulators.
[edit] Standard opened
With the increasing success of VHDL, Cadence decided to make the language available for open standardization. Cadence transferred Verilog into the public domain under the Open Verilog International (OVI) (now known as Accellera) organization. Verilog was later submitted to IEEE and became IEEE Standard 1364-1995, commonly referred to as Verilog-95.
[edit] Verilog 2001
Extensions to Verilog-95 were submitted back to IEEE to cover the deficiencies that users had found in the original Verilog standard. These extensions became IEEE Standard 1364-2001 known as Verilog 2001.
[edit] Superlog/System Verilog
The advent of High Level Verification languages such as OpenVera, and Verisity's E language encouraged the development of Superlog by Co-Design Automation Inc. Co-Design Automation Inc was later purchased by Synopsys. The foundations of Superlog and Vera have been donated to Accellera. It has been transformed and updated to SystemVerilog which will likely become the next IEEE standard.
The latest versions of the language include support for analog and mixed signal modelling. These are referred to as Verilog-AMS.
