Image:Negative differential resistance.svg

See Wikipedia graph-making tips.

Generated in gnuplot with the following script (save as gunn.gp and then open in gnuplot):

set samples 2001
set terminal svg
set output "gunn.svg"

# VI curve with negative differential resistance region
I(V) = (V/2.5-2)**3 + -2*(V/2.5-2) + 4

# Square plot ratio
set size square

# Set range of x and y axes
set xrange [0:10]
set yrange [0:10]

# Create axis tics every 20 numbers, so only the 0 is actually visible
set xtics 20
set ytics 20

# Use 10 axis minor divisions per major division, so there is a division for each integer, but they aren't labeled.
set mxtics 20
set mytics 20

# Axis labels
set xlabel "Voltage (V)"
set ylabel "Current (I)"

# VI curve's plotting style
set style line 1 lt 1 lw 2

# Dotted line style
set style line 2 lt 2 lw 1 
set style arrow 2 nohead ls 2

# Draw dotted lines
set arrow 1 from 3,5.3 to 3,7 as 2
set arrow 2 from 7,3.1 to 7,7 as 2

# Arrowheaded line style
set style line 4 lt 4 lw 1
set style arrow 4 head filled size screen 0.02,15,45 ls 4

# Draw arrows
set arrow 3 from 3.7,7 to 3,7 as 4
set arrow 4 from 6.3,7 to 7,7 as 4

# Label region
set label 1 "Negative differential \nresistance region" at 5,8 c

# Plot the filter response
plot I(x) ls 1 notitle

Then I postprocessed it with Inkscape

21 December 2006

Omegatron and Alessio Damato

see below