Image:Diode mosfet.png

[edit] Summary

Cyril BUTTAY

Current vs Voltage curves of a MOSFET operating in the ohmic region and a diode. At low current values, the voltage drop in the MOSFET is less than in the diode (due to its threshold voltage). When the current increases, the forward voltage drop of the diode does not increase as much as that of the MOSFET. In consequence, for high currents, the losses (current times voltage) are less in the diode than in the MOSFET. However, by connecting several MOSFETs in parallel, it is possible to reduce their R_DSon as can be seen in the figure (orange curve). Paralleling several diodes will not modify their threshold voltage.

This file has been generated using gnuplot 4.0 and the following source code:

# This file is used to plot the U=f(I) of a diode and
# a MOSFET to show the benefits of synchronous rectification

# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24 color solid
set encoding iso_8859_15
unset title
set line style 1 lt 1 lw 3 pt 0 ps 0
set line style 2 lt 3 lw 3 pt 0 ps 0
set line style 3 lt 7 lw 1 pt 0 ps 0
set line style 4 lt 8 lw 3 pt 0 ps 0
set border 15 lt 7 lw 4
set mxtics 
set mytics 
set grid xtics ytics
set xlabel "Current [A]"
set ylabel "Voltage [V]"
set format y '%0.1f'
set format x "%0.0f"
set key bottom right
set samples 1000
# diode forward voltage
diode(x)=0.026*log(x*1e9+1)
#MOSFET resistive behaviour, rdson=20mohms
MOSFET(x)=x*0.02
#MOSFET resistive behaviour, rdson=10mohms
MOSFET2(x)=x*0.01
#arrows
set arrow 1 from 0,0.7 to 31.6,0.7 heads ls 3
set arrow 2 from 31.6,0.7 to 60,0.7 heads ls 3
set arrow 3 from 31.6,0.6 to 31.6, 0.72 nohead ls 3
#labels
set label 1 'less losses in the 20 m{/Symbol W} MOSFET' center at 16,0.74 font "Times, 18"
set label 2 'less losses in the diode' center at 46,0.74 font "Times, 18" front

set output "diode_mosfet.eps"
plot [0:60][0:1] MOSFET(x) ls 1 title 'MOSFET R{_{DSon}}=20 m{/Symbol W}',\
        MOSFET2(x) ls 4 title 'MOSFET R{_{DSon}}=10 m{/Symbol W}',\
        diode(x) ls 2 title 'Diode'

[edit] Licensing

I, the copyright holder of this work, hereby publish it under the following licenses: Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation license, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation license". Aragonés | العربية | Asturianu | Български | বাংলা | ইমার ঠার/বিষ্ণুপ্রিয়া মণিপুরী | Brezhoneg | Bosanski | Català | Cebuano | Česky | Dansk | Deutsch | Ελληνικά | English | Esperanto | Español | Eesti | Euskara | فارسی | Suomi | Français | Gaeilge | Galego | עברית | Hrvatski | Magyar | Bahasa Indonesia | Ido | Íslenska | Italiano | 日本語 | ქართული | ភាសាខ្មែរ | 한국어 | Kurdî / كوردی | Latina | Lëtzebuergesch | Lietuvių | Bahasa Melayu | Nnapulitano | Nederlands | ‪Norsk (nynorsk)‬ | ‪Norsk (bokmål)‬ | Occitan | Polski | Português | Română | Русский | Slovenčina | Slovenščina | Shqip | Српски / Srpski | Svenska | తెలుగు | ไทย | Türkçe | Українська | اردو | Tiếng Việt | Volapük | Yorùbá | ‪中文(中国大陆)‬ | ‪中文(台灣)‬ | +/- This file is licensed under the Creative Commons Attribution ShareAlike license versions 2.5, 2.0, and 1.0 العربية | Български | Català | Česky | Dansk | Deutsch | English | Español | Euskara | فارسی | Français | עברית | Italiano | 日本語 | 한국어 | Lietuvių | Nederlands | Polski | Português | Русский | Svenska | தமிழ் | Türkçe | 中文 | 中文 | +/- You may select the license of your choice.

• Synchronous rectification