Image:BaseballProjectileGraph.svg

From Wikipedia, the free encyclopedia

• Image
• File history
• File links

[edit] Summary

Created myself to replace using Gnuplot, labels added afterwards:

# http://en.wikipedia.org/wiki/Wikipedia:How_to_create_graphs_for_Wikipedia_articles#SVG
set terminal svg enhanced size 1000 1000 fname "Times" fsize 36

# Sensible ranges
set yrange [-10:60]
set xrange [0:250]

# "ground"
set xzeroaxis lt -1

# Constants given in the article.
g=9.81
vt=33.0
v0=44.7
m=0.145
k=(m*g)/vt
theta=pi/4 # 45 deg.

# Some stuff not included in gnuplot 4.0-0.
e=2.71828183 #euler's constant
ln(q)=log(q)/log(e)

# Work out the time from the x coord (rearrangement by Derive).
tfromx(x)=-m*ln((m*v0*cos(theta)-k*x)/(m*v0*cos(theta)))/k

# Colours as article.
set style line 1 lt 2
set style line 2 lt 1

# Equation without air-resistance.
na(x)=x*tan(theta) - g*x**2/(2*(v0*cos(theta))**2)

# Equation with air-resistance.
ar(x)=(m*v0*sin(theta)/k)*(1-e**(-k*tfromx(x)/m)) - (m**2*g/k**2)*(e**(-k*tfromx(x)/m) + k*tfromx(x)/m - 1)

# Go!
plot na(x) ti "Without air-resistance", ar(x) ti "With air-resistance"

However, it seems that the SVG renderer here is completely different to local, if anyone wants to fix it, feel free.

[edit] Licensing

I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide. In case this is not legally possible, I grant any entity the right to use this work for any purpose, without any conditions, unless such conditions are required by law.

File history

Click on a date/time to view the file as it appeared at that time.

• Search for duplicate files
• Edit this file using an external application

  See the setup instructions for more information.

File links